@echo off
chcp 65001 >nul

set "BAT_DIR=%~dp0"
set "BAT_PATH=%BAT_DIR%raskidator.bat"

echo Создание install-context-menu.reg с путём: %BAT_PATH%
echo.

>"%BAT_DIR%install-context-menu.reg" (
echo Windows Registry Editor Version 5.00
echo.
echo ; Контекстное меню — правый клик в пустом месте папки
echo [HKEY_CLASSES_ROOT\Directory\Background\shell\Raskidator3000]
echo @="Raskidator-3000"
echo "Icon"="\"%BAT_PATH:\=\\%\",0"
echo.
echo [HKEY_CLASSES_ROOT\Directory\Background\shell\Raskidator3000\command]
echo @="\"%BAT_PATH:\=\\%\" \"%%V\""
echo.
echo ; Контекстное меню — правый клик на папке
echo [HKEY_CLASSES_ROOT\Directory\shell\Raskidator3000]
echo @="Raskidator-3000"
echo "Icon"="\"%BAT_PATH:\=\\%\",0"
echo.
echo [HKEY_CLASSES_ROOT\Directory\shell\Raskidator3000\command]
echo @="\"%BAT_PATH:\=\\%\" \"%%1\""
echo.
echo ; Библиотеки (Pictures, Music, Videos, Documents)
echo [HKEY_CLASSES_ROOT\LibraryFolder\Background\shell\Raskidator3000]
echo @="Raskidator-3000"
echo "Icon"="\"%BAT_PATH:\=\\%\",0"
echo.
echo [HKEY_CLASSES_ROOT\LibraryFolder\Background\shell\Raskidator3000\command]
echo @="\"%BAT_PATH:\=\\%\" \"%%V\""
)

echo Готово. Запусти install-context-menu.reg двойным кликом и подтверди добавление в реестр.
echo.
echo Если ранее устанавливал — сначала удали старые ключи:
echo   reg delete "HKEY_CLASSES_ROOT\Directory\Background\shell\Raskidator3000" /f
echo   reg delete "HKEY_CLASSES_ROOT\Directory\shell\Raskidator3000" /f
pause